% These figures to be made on the APS as single "characters".

mode_setup;
standard_pen=savepen;

beginchar(1,6cm#,2.6cm#,0); "Figure 3aa";
pickup standard_pen;
for d=0 step 10 until 120:
 draw (0,0){angle 60}..(6cm,0){angle-d}; endfor
endchar;

beginchar(2,6cm#,1cm#,1.8cm#); "Figure 3bb";
pickup standard_pen;
for d=0 step -10 until -90:
 draw (0,0){angle 60}..(6cm,0){angle-d}; endfor
endchar;

beginchar(3,6cm#,2.6cm#,0); "Figure 3cc";
pickup standard_pen;
for d=0 step 10 until 120:
 draw (0,0){angle 60}..bounded..(6cm,0){angle-d}; endfor
endchar;

def overdraw expr c = erase fill c; draw c enddef;
beginchar(4,40pt#,100pt#,0); pickup standard_pen; "Figure 13aa";
path S; S=((0,1)..(2,0)..(4,2)..(2,5.5)..(0,8)..(2,10)..(3.5,9)) scaled 9pt;
for k=0 upto 35: overdraw fullcircle scaled 3mm
 shifted point k/35*length S of S; endfor
endchar;

def overdraw expr c = begingroup picture region; region:=nullpicture;
 interim turningcheck:=0; addto region contour c; cull region excluding (0,0);
 cullit; addto currentpicture also -region; cullit; draw c endgroup enddef;
def link(expr n) = overdraw subpath 1/3(n,n+1) of M --
		subpath 1/3(n+25,n+24) of M -- cycle enddef;
beginchar(5,1.25in#,.5in#,0); pickup standard_pen; "Figure 13bb";
z1=(20,-13); z2=(30,-6); z3=(20,1); z4=(4,-7);
 z5=(-12,-13); z6=(-24,-4); z7=(-15,6);
path M; M=(origin..z1..z2..z3..z4..z5..z6..z7..
	    origin..-z7..-z6..-z5..-z4..-z3..-z2..-z1..cycle)
  scaled (h/26) shifted (.5w,.5h);
for k=1 upto 12: link(k+11); link(12-k); endfor
endchar;

end